Raising the Flag on Mount Yo Momma — 64 of 87

Section Mixing drinks

The mix is a drink. The description is "It's a [color] mix of [compound1] and [compound2]." The printed name is "[if spiced]spiked [end if][compound1] [compound2]".

The mix has a drink that varies called compound1. The mix has a drink that varies called compound2.

[couldn't find a better way to do this.]

Understand "cola" as the mix when cola is mixed.

Understand "tonic" and "mineral" and "water" as the mix when tonic is mixed.

Understand "gin" as the mix when gin is mixed.

Understand "wine" as the mix when wine is mixed.

Understand "beer" as the mix when beer is mixed.

Understand "vodka" as the mix when vodka is mixed.

Definition: a drink is mixed if it is compound1 of the mix or it is compound2 of the mix.

Check mixing a drink into something when the second noun is not a drink and the second noun is not the plant:

say "That would just make a mess." instead.

Check mixing a drink into a drink when the noun is the mix or the second noun is the mix:

say "There's no more room in the glass to mix more drinks in." instead.

Check mixing a drink into a drink when the mix is enclosed by the location:

say "You should do something to [the mix] before you start mixing more." instead.

Check mixing a drink into a drink when the noun is the second noun:

say "You can't mix [the noun] into itself!" instead.

Carry out mixing a drink into a drink:

if the noun is non-alcoholic:

now the compound1 of the mix is the second noun;

now the compound2 of the mix is the noun;

otherwise:

now the compound1 of the mix is the noun;

now the compound2 of the mix is the second noun;

reset the noun;

reset the second noun;

now the color of the mix is the additive color of the color of the noun and the color of the second noun;

if the noun is alcoholic or the second noun is alcoholic:

now the mix is alcoholic;

otherwise:

now the mix is non-alcoholic;

if the noun is spiced or the second noun is spiced:

now the mix is spiced;

now the player is carrying the mix;

say "You pour [the noun] into [the second noun] and create [color of the mix] [mix]."

To decide which drink-color is the additive color of (color1 - a drink-color) and (color2 - a drink-color):

if color1 is clear:

decide on color2;

if color2 is clear:

decide on color1;

if color1 is color2:

decide on color1;

otherwise:

decide on brown.

[There's a major disambiguation problem with the mixed drinks. Instead of digging into the root of the problem, I'll just take the easy way out.]

Instead of putting the mix on the counter:

try giving the mix to the barkeep.

Instead of dropping the mix when the location is the Bar:

try giving the mix to the barkeep.