Raising the Flag on Mount Yo Momma — 62 of 87

Chapter Drinks

Drink-color is a kind of value. Drink-colors are clear, brown, black, and red.

A drink is a kind of thing. A drink can be alcoholic or non-alcoholic. A drink is usually alcoholic. The indefinite article of a drink is "a glass of". A drink has a drink-color called color. The color of a drink is usually clear.

A drink can be safe, primed for drugging, or spiced. A drink is usually safe.

Understand "drink" and "glass" and "glass of" as the drink.

The cola is a non-alcoholic drink in the Bar. The description is "Ah, cola. A classic." The color is black. Understand "coke" as the cola.

The tonic is a non-alcoholic drink in the Bar. The description is "It's like water, but with bubbles." Understand "mineral" and "water" as the tonic.

The gin is a drink in the Bar. The description is "Gin, the grampa's choice."

The wine is a drink in the Bar. The description is "When beer just isn't fine enough." The color is red.

The beer is a drink in the Bar. The description is "Beer. The cause of, and solution to, all of life's problems." The color is brown.

The vodka is a drink in the Bar. The description is "Vodka is almost pure alcohol. The best way to get drunk quickly."

Before printing the name of a spiced drink while taking inventory:

say "spiked ".

Understand "spiked" and "spiced" and "drugged" as a drink when the item described is spiced.

Understand "alcohol/alcoholic" and "booze" as a drink when the item described is alcoholic.

Understand "non-alcoholic" as a drink when the item described is non-alcoholic.

Instead of inserting a drink into something:

try mixing the noun into the second noun.

Instead of drinking a drink:

if the noun is alcoholic:

say "Better keep your senses sharp.";

otherwise:

say "You're not especially thirsty."

Instead of drinking a spiced drink:

say "No way! You'd probably be knocked out cold!"

Instead of tasting a drink:

try drinking the noun.

Instead of attacking a bought drink:

say "That would just spill the contents everywhere."

Definition: a drink is masked alcohol if it is the mix and it is alcoholic and the color of it is black.

To reset (glass - a drink):

now the glass is safe;

if glass is the mix:

remove mix from play;

otherwise:

now the glass is in the Bar.

The hint list of a drink is usually the table of unbought drink hints.

Table of unbought drink hints

Table of bought drink hints