Sparkle — 101 of 108

Part 2 - Actions

Instead of meditating when the player can see the barking dog:

say "The barking of the dog makes it impossible to meditate here."

After changing the dog into the familiar flute for the first time:

say "[We] clear [our] mind and concentrate on the dog, imagining its counterpart nature. The truth becomes obvious -- a dog is a flute, and a flute is a dog, and there is no difference between the two. Sparkles start flying from all over the dog as the Universe bends to accept the reality [we] have discovered.

The sparkling stops and where the dog used to stand, there's a small koudi flute lying on the grass."

To decide whether the dog is dangerous:

if the dog is tame:

decide no;

if the location is the Hotel gates and the location of the flute is the Garden and the gate-door is closed:

decide no;

if the location is the Dining hall and the flute is in the left dumbwaiter:

decide no;

decide yes. [1]

Check changing the flute into the dog when the dog is dangerous:

say "It might not be wise to bring the dog back when he's in such a bad mood and can readily attack [us]." instead.

After changing the flute into the angry dog:

say "The flute sparkles and is soon changed back into the dog, who resumes barking after noticing [us]."

Check playing the angry dog:

say "He doesn't look very playful at the moment." instead.

Check playing the tame dog:

say "The dog might feel like playing, but [we] certainly don't." instead.

After smelling the dirty dog:

say "Believe it or not, he's not smelling of roses."

After smelling the clean dog:

say "He smells like a slightly damp dog."

After listening to the angry dog:

say "He's barking."

Check taking the dog:

say "He's way too heavy to lift." instead.

Check throwing something at the dog:

say "Better not." instead.

Check touching the angry dog:

say "[We] would rather keep [our] fingers." instead.

After touching the tame dog:

say "Good boy."

Check washing the dirty dog with:

say "It would be a lot of work to wash the dog[if the dog is angry] and he wouldn't let me do it anyway[end if]. [We] need to find another way if [we] want it cleaned." instead.

Check eating the dog:

say "That's racist." instead.

Instead of throwing the chopstick at the dog:

say "The dog catches the chopstick from air and shreds it to sawdust.";

remove the chopstick from play.

A persuasion rule for asking the dog to try doing something:

say "He seem to either not understand what [we]['re] saying or refuses to do so.";

persuasion fails.