Escapade!
An interactive fiction by Juhana Leinonen (2008) - the Inform 7 source text
Contents
Previous
Next
Complete text
The sticker is a thing. It is insubstantial, useful and middle. It can be fast glued or slightly glued. It is fast glued. The description is "The sticker has a small red circle and the words 'Push to open' printed on it." The printing is "'Push to open.'".
After examining something when the sticker is part of the noun and the noun is not the trapdoor:
say "The sticker is attached to [it-them of the noun]."
Understand "red" and "circle" and "word/words/text" and "label" as the sticker.
Check pushing the sticker:
if the sticker is part of the player or the sticker is part of the creature:
continue the action;
otherwise if the sticker is not part of the celldoor and ( trapdoor is open or the sticker is not part of the trapdoor ) and ( the encyclopedia is open or the sticker is not part of the encyclopedia ):
say "Nothing happens." instead.
Report pushing the sticker when the sticker is part of the player:
say "Your mouth drops wide open.[if the creature is present][line break][c]Tee hee,' [the creature] snickers." instead.
Report pushing the sticker when the sticker is part of the creature:
say "The creature's mouth swings wide open.
'[one of]Heh[or]Hee[at random],' you giggle.[if the creature is present][line break][one of][c]Very funny,' [the creature] grunts.[or][c]Stop that!' the creature says.[or][c]This is getting tiresome,' [the creature] says.[stopping]" instead;
Carry out pushing the sticker when the sticker is part of the trapdoor:
now the trapdoor is open;
now the switch is a part of the trapdoor.
Report pushing the sticker when the sticker is part of the trapdoor:
say "There's a click and the trapdoor drops open. Underneath you see another room very similar to this one.
'[if the tongue is numb]Ey ey[otherwise]Hey hey[end if]!' you rejoice[if the creature is present]. [c]Oh joy,' [the creature] cheers laconically[end if]." instead.
Carry out pushing the sticker when the sticker is part of the encyclopedia:
say "[The encyclopedia]'s cover swings open.";
try opening the encyclopedia.
Report pushing the sticker when the sticker is part of the encyclopedia:
do nothing instead.
Instead of pushing the sticker when the sticker is part of the celldoor:
mark the escape down as "opening the cell door with the sticker";
say "There's a click and the cell door swings violently open. You don't stop to wonder how and why it worked when you take off.";
say "'HEY!' the guard yells behind you. You keep running through the corridors and manage to lose him from your tail.";
pause the cutscene;
say "The castle's twisty corridors are like a maze and very soon you are completely lost. After wandering for some time longer you come across a trapdoor in the floor. 'Can't hurt to try this one too,' you think to yourself.";
pause the cutscene;
if the trapdoor is open:
say "You drop down the trapdoor and find yourself staring at [the creature]'s oblong face. You're back in the cell.";
say "'[if the tongue is numb]Whah eh... how eh[otherwise]What the... how the[end if]...' you stutter.";
say "[c]Tee hee,' [the creature] giggles.";
otherwise:
say "You drop down the trapdoor and find yourself staring at the guard's ugly face.[paragraph break]'Well HELLO,' he shouts, grabs you by the neck and throws you back in the cell.[silent c]";
remove the sticker from play.
Instead of taking the fast glued sticker:
say "It's glued fast. It doesn't come off with bare hands."
Instead of taking the slightly glued sticker when the sticker is part of something:
say "You peel the sticker off.";
now the player carries the sticker.
Instead of pouring the glue remover on the sticker:
say "The glue remover is effective immediately and the sticker comes off easily.";
remove the glue remover from play;
now the sticker is slightly glued;
now the player carries sticker.
Instead of tying the slightly glued sticker to something (called the target):
if the sticker is part of something (called the surface):
say "(first taking the sticker from [the surface])[command clarification break]";
say "You slap the sticker on [the target].";
if the target is the creature and the creature is present:
say "[line break][c]Hey,' [the creature] protests.";
now the sticker is part of the target.
Instead of putting the sticker on something:
try tying the sticker to the second noun.
Instead of inserting the sticker into something:
try tying the sticker to the second noun.
Test sticker with "test c/remove clothes/trade clothes/wear clothes/look under rug/pour glue remover on sticker".