Escapade!
An interactive fiction by Juhana Leinonen (2008) - the Inform 7 source text
Contents
Previous
Next
Complete text
The metalplate is part of the celldoor. It is scenery and by the door. The printed name is "metal plate". The description is "[if the metalplate is shut]There's a metal plate embedded in the door on the eye level, about three centimeters high and thirty centimeters wide.[otherwise]Where there used to be a metal plate now two eyes stare at you.".
Definition: The metalplate is slid open rather than shut if the guard is in the cell.
Understand "rectangular" as the metalplate.
Understand "metal" as the metalplate.
Understand "plate" as the metalplate.
Understand "eye hole" and "eyehole" as the metalplate.
Understand "metal" and "plate" as the metalplate.
Instead of taking the metalplate:
say "There's nothing to get a hold of. It doesn't seem like it could be removed.".
Instead of entering the metalplate:
say "It's way too small.[if the creature is present][paragraph break][c]Or you're just way too big,' [the creature] notes.".
Instead of searching the metalplate when the metalplate is slid open:
try examining the guard.
Instead of opening the metalplate:
say "[if the metalplate is shut]There's no obvious mechanism to open it from this side.[otherwise]It's already open.".
Instead of closing the metalplate:
say "[if the metalplate is slid open]There's no obvious mechanism to close it from this side.[otherwise]It's already closed.".
Instead of attacking the metalplate:
try knocking on the celldoor.
Instead of touching the metalplate:
if the metalplate is shut:
say "It feels metallic.";
otherwise:
try touching the guard.
Instead of pushing, pulling or turning the metalplate:
if the metalplate is shut:
say "It doesn't move.";
otherwise:
try pushing the guard.
Instead of smelling the metalplate:
if the metalplate is slid open:
try smelling the guard;
otherwise:
try smelling the celldoor.
Instead of tasting the metalplate:
try tasting the celldoor.
Instead of rubbing the metalplate:
say "It's a bit shinier now.".
Instead of knocking on the metalplate:
if the metalplate is shut:
try knocking on the celldoor;
otherwise:
try knocking on the guard.