Raising the Flag on Mount Yo Momma — 87 of 87

Juhana Leinonen

Release 3

Chapter Jukebox

The jukebox is in the Hall of Fame. "An old jukebox sits under the pictures." It is fixed in place. The description is "The jukebox looks like a retro vinyl player but under the hood it plays MP3s like everything else. The machine controls all the music playing in the club, so when somebody chooses a new song, the whole club has to listen to that."

Understand "retro" and "vinyl" and "player" and "machine" and "juke" and "box" as the jukebox.

A sound-volume is a kind of value. Sound-volumes are low, medium and high.

The jukebox has a sound-volume called volume. The volume of jukebox is medium.

The jukebox can be paid or unpaid. The jukebox is unpaid.

After examining the jukebox:

try examining the jukebox-controls;

try examining the coinslot.

Instead of jamming the jukebox with the bubblegum:

say "That's a good idea, but you need to be a bit more specific."

Instead of inserting the bubblegum into the jukebox:

try jamming the jukebox with the bubblegum.

Instead of inserting the coins into the jukebox:

try inserting the coins into the coinslot.

Instead of setting the jukebox to:

try playing the jukebox.

Instead of playing the jukebox:

say "The jukebox is operated by inserting coins and pushing the buttons."

Check thinking about something that is a part of the jukebox:

try thinking about the jukebox instead.

Check thinking about something that is a part of something that is a part of the jukebox: [we could just say "check thinking about a jukebox-button, but this is much more fun way to phrase it.]

try thinking about the jukebox instead.

The hint list of Jukebox is the table of jukebox hints.

Table of jukebox hints

hint

"The jukebox is used to change the music that's being played in the club."

"The jukebox is coin operated. You need to find coins before you can use it."

"The best place to look for coins is where coins are most used."

"The arcade machines are also coin operated."

"Search the arcade machines."

Chapter Coin slot

The coinslot is a part of the jukebox. The description is "The jukebox is operated by inserting coins into the slot."

Understand "coin slot" and "slot" as the coinslot.

Check inserting coins into the coinslot:

ignore the can't insert into what's not a container rule;

ignore the standard inserting rule.

Carry out inserting coins into the coinslot:

now the jukebox is paid.

Report inserting coins into the coinslot:

say "The coin tumbles inside the machine." instead.

Instead of inserting coins into the coinslot when the coinslot is jammed:

say "The bubblegum is blocking the coin slot."

Instead of inserting coins into the coinslot when the jukebox is paid:

say "You've already paid for the next song."

Check playing the jukebox when the player is not carrying the coins:

say "The jukebox is coin-operated and you don't have any coins." instead.

Check playing the jukebox when the jukebox is paid:

say "You have to select the song by pushing the buttons."

Check playing the jukebox when the jukebox is unpaid:

say "The jukebox is coin-operated."

Chapter Jukebox controls

The jukebox-controls are part of the jukebox. They are plural-named and privately-named. The description is "The buttons are labeled 'rap', 'r&b', 'jazz', 'rock', 'techno', and something that has most of the letters scraped off, leaving only 'ass'. The button labeled '[current selection of the jukebox]' is currently selected.". The printed name is "jukebox controls".

Understand "buttons" and "controls" and "keys" and "jukebox controls/buttons/keys" as the jukebox-controls.

Instead of pushing jukebox-controls:

say "You have to specify which button to press.";

try examining the jukebox-controls.

Jukebox-button is a kind of thing. Understand "button" and "key" as a jukebox-button. A jukebox-button is always proper-named.

A jukebox-button has some text called the starting description.

The description of a jukebox-button is usually "The button is labeled '[printed name of the item described]'."

Instead of pushing a jukebox-button when the noun is the current selection of the jukebox:

say "The button '[noun]' is already selected."

Instead of pushing a jukebox-button when the jukebox is unpaid:

if the player is carrying the coins:

clarify "first inserting a coin into the jukebox";

silently try inserting coins into the coinslot;

if the jukebox is paid:

start the noun music;

otherwise:

say "The button refuses to budge. The machine must require a coin to be inserted first."

Instead of playing a jukebox-button:

try pushing the noun.

Instead of pushing a jukebox-button when the jukebox is paid:

start the noun music.

To start the/-- (selection - jukebox-button) music:

if the current selection of the jukebox is jammed:

say "You try to push the '[selection]' button but it refuses to budge. The gum is blocking the '[current selection of the jukebox]' button and prevents the machine from operating.";

otherwise:

say "You push the '[selection]' button and the '[current selection of the jukebox]' button pops back up. [starting description of the selection].";

now the current selection of the jukebox is the selection;

now the jukebox is unpaid;

if the selection is the ass:

now the printed name of ass is "classical".

The rap is a jukebox-button. It is part of the jukebox-controls. The starting description of rap is "Gangsta rap starts booming".

The techno is a jukebox-button. It is part of the jukebox-controls. The starting description is "A steady stream of low thump-thump-thump beats fill the air".

The r&b is a jukebox-button. It is part of the jukebox-controls. The starting description is "Latest R&B starts flowing from the speakers".

Understand "rnb" and "r'n'b" as r&b.

The jazz is a jukebox-button. It is part of the jukebox-controls. The starting description is "Smooth jazz sounds start to vibrate in the room".

The rock is a jukebox-button. It is part of the jukebox-controls. The starting description is "It's time to rock'n'roll".

Understand "rock'n'roll" as the rock.

The ass is a jukebox-button. It is part of the jukebox-controls. The starting description is "A soothing classical symphony starts playing".

Understand "classical" as the ass.

The jukebox has a jukebox-button that varies called current selection. The current selection of the jukebox is rap.

Section Jamming jukebox buttons

Definition: a thing is jukebox-jammable if it is a jukebox-button or it is the coinslot.

Check jamming a jukebox-jammable thing with the bubblegum:

ignore the block jamming with rule.

Carry out jamming a jukebox-jammable thing with the bubblegum:

now the bubblegum is part of the noun.

Report jamming a jukebox-button with the bubblegum:

say "You stick the bubblegum in and around the [noun] button."

Report jamming the coinslot with the bubblegum:

say "You stick the bubblegum inside the coin slot."

Definition: a jukebox-button is jammed if the bubblegum is part of it and it is the current selection of the jukebox.

Definition: the coinslot is jammed if the bubblegum is part of it.

Definition: the jukebox is jammed if a jukebox-button is jammed or the coinslot is jammed.

Instead of inserting bubblegum into a jukebox-jammable thing:

try jamming the second noun with the bubblegum.

Instead of putting something on a jukebox-button:

try jamming the second noun with the noun.

Instead of putting something under a jukebox-button:

try jamming the second noun with the noun.

Instead of taking the bubblegum when the bubblegum is part of a jukebox-jammable thing:

if the player is carrying a card (called the scraper):

clarify "with [the scraper]";

try scraping the bubblegum with the scraper;

otherwise:

say "You don't have anything to scrape the gum off with, and you wouldn't touch it with bare hands."

Chapter Volume knob

The volume knob is a thing. The description is "The knob is apparently for adjusting the volume of the music being played. It can be set to low, medium or high. At the moment it's set on [volume of jukebox]."

Understand "volume" as the volume knob.

Instead of searching the jukebox:

say "On the back side of the jukebox you find a knob.";

now the volume knob is part of the jukebox;

now the volume knob is familiar.

Instead of setting the volume knob to "low/silent/quiet":

if the volume of the jukebox is low:

say "The music is already playing silently.";

otherwise:

say "You turn the music down.";

now the volume of jukebox is low.

Instead of setting the volume knob to "high/loud":

if the volume of the jukebox is high:

say "The music is already booming.";

otherwise:

say "You turn the music up.";

now the volume of jukebox is high.

Instead of setting the volume knob to:

say "The knob doesn't have that setting."

Instead of setting the jukebox to when the volume knob is known:

clarify "setting [the volume knob] to [the topic understood]";

try setting the volume knob to the topic understood.

Instead of setting the music to when the volume knob is known and the location is the Hall of Fame:

clarify "setting [the volume knob] to [the topic understood]";

try setting the volume knob to the topic understood.

Instead of turning the knob:

say "The knob can be turned to low, medium or high."

Section Music

The music is a backdrop. It is everywhere. It is distant.

A distant objects rule for the music:

say "It's music. You can't do that to it.";

rule fails.

Instead of examining the music:

try listening to the music.

Before listening to the music:

say "Some [current selection of the jukebox] is playing[if the volume of the jukebox is high] at ear-piercing volume[end if]." instead.

Before listening to the music when the volume of the jukebox is low:

say "The music is playing on so low volume it's barely audible." instead.

Instead of listening to the location:

try listening to the music.

Does the player mean doing something with the music:

it is very unlikely.

Does the player mean listening to the music:

it is very likely.

Part Stage

The player is in the Stage.

East of the Stage is nowhere. West of the Stage is nowhere. Southwest of the Stage is nowhere. Southeast of the Stage is nowhere.

The description of the Stage is "You're standing dumbfounded and humiliated on the stage of the Compass Club. There's nothing left to do than to swallow your defeat and climb down the stage."

The printed name of the Stage is "[one of][or]The Stage[stopping]". [this removes the name when the play begins]

Instead of going down while the location is the Stage:

try going south.

Instead of going up when the player is in a room:

say stage-entering tip.

Instead of going to the stage:

say stage-entering tip.

To say stage-entering tip:

say "When you feel you're ready to challenge Gus again you can CLIMB ON STAGE."

Instead of moving to while the location is the Stage and the noun is not the Dance floor and the noun is not the Stage:

clarify "first stepping down the stage";

try going south.

Instead of exiting while the location is the Stage:

try going south.

Understand "swallow defeat" or "swallow your/my defeat" as a mistake ("Gulp.").

Chapter Insult Combat

Instead of moving to the Stage when the location is not the Stage:

say "You climb on the stage. The music pauses and an announcement booms from the speakers: [italic type]'We haaave a challenger!'[roman type][press space]";

wait for any key;

say "A crowd starts gathering on the dance floor. The anticipation of a battle is thick in the air.

[italic type]'Our challenger tonight is Jen, a local girl who is taking on the current champion, Gus!'[roman type]

Gus trots on the stage, clapping his hands, working the crowd. The masses cheer and yell his name.

[italic type]'[announcer assesment of number of wins]!'[roman type]

Gus stomps on his side of the stage and turns to face you. The crowd goes silent.

'[yo momma insult]!'[paragraph break]";

if there's unused winning intel available:

repeat through table of winning intel:

if revealed entry is true and used entry is false:

win a battle with the intel entry;

change used entry to true;

if the win count is 3:

win the game;

otherwise if the win count is 1:

say "[line break][italic type]'The challenger wins! She is now one third on her way to becoming the champion! Give a big hand for Jen everybody!'[roman type][paragraph break]'Beginner's luck,' Gus mutters when you step down from the stage.";

otherwise:

say "[line break][italic type]'The challenger wins again! Uuun-be-lievable! That's two wins for her and she is only one victory away from becoming the new champion!'[roman type][paragraph break]Gus is looking considerably nervous. He avoids eye contact when you walk past him and into the cheering crowd.";

break;

otherwise:

say "That was a tough one. Sweat is starting to flow down your face.[paragraph break]'[hesitation] [lame insult].'

Oh dear. The crowd boos and whistles you off the stage. You were clearly not prepared well enough for this. Gus gives you a condescending look as you are forced to walk down the stage in defeat.";

if win count is not 3:

say press space;

wait for any key;

move the player to the dance floor.

To say hesitation:

say "[one of]Oh yeah?[run paragraph on][or]Well...[run paragraph on][or]Is that so?[run paragraph on][or]You know...[run paragraph on][at random]"; [have to do this to get the run paragraph on to work]

Table of winning intel

intel revealed used

"tag" false false

"wart" false false

"whale" false false

To decide whether (knowledge - some text) has inspired us:

choose row with intel of knowledge in the table of winning intel;

decide on revealed entry.

To decide whether there's unused winning intel available:

repeat through table of winning intel:

if the revealed entry is true and the used entry is false:

decide yes;

decide no.

To decide which number is the win count:

let counter be 0;

repeat through table of winning intel:

if the used entry is true:

increase counter by 1;

decide on counter.

To get inspired by (inspiration - some text):

choose row with intel of inspiration in the table of winning intel;

change the revealed entry to true.

To say announcer assesment of number of wins:

if the win count is:

-- 0:

say "It takes three wins to beat the prevailing champion. With no victories so far she still has a long road ahead of her";

-- 1:

say "She has succeeded in one battle, but was it just a stroke of luck? We'll soon find out -- our challenger needs two more victories to win the championship";

-- 2:

say "With two victories under her belt, she is only one, yes, one win away from the championship title".

To win a battle with (intel - some text):

if intel is:

-- "tag":

say "Without blinking you look him straight in the eye and say: 'Yo momma's so poor she shops for yo rags at the Cheap-O-Mart.'[paragraph break]The crowd gasps. Gus's face turns white. 'I... Your... [lame insult]!' he stammers. The crowd hesitates, as if not knowing what happened. Then they start booing.";

award 5 points for "revealing Gus's momma shops at Cheap-O-Mart";

-- "wart":

say "You have the insult and you know how to use it. 'Yo momma's so ugly her warts went to see the doctor to have her removed.'[paragraph break]The crowd goes wild. They can barely hear Gus stuttering: '..no way... [lame insult]! I mean [lame insult]!'";

award 5 points for "telling the whole world about Gus's momma's hideous wart";

-- "whale":

say "Here the quip comes, all ready to whip Gus's ass. 'Yo momma's so fat she fell into the whale pool and the staff rescued the whale by mistake.'[paragraph break]You can practically hear Gus's jaw fall on the floor. 'Yo... Yo... [lame insult]...'[paragraph break]The crowd is cheering, and they're cheering for you.";

award 5 points for "comparing Gus's momma to a large sea mammal".

To win the game:

say press space;

wait for any key;

say "[paragraph break]Suddenly lights of all colors start flashing and music turns into heroic fanfares. The announcer goes ballistic. [italic type]'U-U-U-UNBELIEVABLE! Ladies and Gentlemen! We have a NEW CHAMPION!'[roman type]

The sound of the crowd is incredible. They cheer for their new hero -- you! You are carried out above the crowds chanting your name. A life of celebrity, fame and fortune has just opened before you.

Just as the celebrating masses carry you out the door you see Joe Mahma in the corner table, giving a brief nod of approval before retreating back into the shadows. He is smiling and you're almost sure you saw a glint of a tear in his eye.";

end the game in victory.

Part VIP lounge

The description of the VIP lounge is "This area is reserved to those with VIP passes. There are cushy red sofas to sit on and you don't have to worry about drunken idiots crashing your table."

Understand "corner" as the VIP lounge.

Definition: The VIP lounge is accessible if the guard is asleep.

A distant objects rule for something (called the far-away target) enclosed by the VIP lounge when the VIP lounge is not accessible:

say "'Ma'am, this area is off limits for anyone without a VIP pass,' the guard says when you try to approach [the far-away target].";

rule fails.

Chapter Sofas

The sofas are scenery in the VIP lounge. They are plural-named. The description is "The sofas are red and they have plushy cushions that make you just sink into them."

Understand "sofa/couch/couches" and "red" and "cushy/plushy" and "cushion/cushions" as the sofas.

The sofas are distant.

Instead of entering the sofas:

say "There's no time to rest now!"

Instead of searching the sofas when the VIP pass is not handled:

say "Among other assorted crap fallen from people's pockets like candy wrappers and used paper tissues you find a VIP pass.";

now the player carries the VIP pass;

remove the hints from the sofas;

award 1 point for "finding the VIP pass".

Instead of searching the sofas:

say "There's nothing useful hidden in the sofas anymore."

The hint list of the sofas is the table of no access hints.

Table of no access hints

hint

"You need to get past the guard before you can do anything else."

Table of sofa hints

hint

"Sofas are made for sitting on."

"Sometimes when people sit on sofas, stuff fall out of their pockets."

"Try searching the sofas."

Chapter Guard

The guard is a man in the VIP lounge. "[if vigilant]A guard is making sure no one without a pass gets in[otherwise]The guard is lying passed out on one of the sofas[end if][if the guard is vigilant and the setting of the thermostat is warm]. He looks quite uncomfortable[end if].". The description is "[if vigilant]The guard is standing just outside the VIP area with his hands crossed. He wears a black suit and a pair of sunglasses.

A ventilation duct blows [setting of the thermostat] air right to where the guard is standing[end if][if the guard is vigilant and the setting of the thermostat is warm]. Sweat has made his hair stick to his head[end if][if vigilant].[otherwise]He's resting on the couch, looking peaceful."

The guard can be vigilant or asleep. The guard is vigilant.

Instead of talking to the guard when the guard is vigilant:

say "'On duty. Can't talk,' the guard says bluntly."

Check talking to the guard when the guard is asleep:

say "He's fast asleep. Not much of a talker, but a good listener." instead.

Instead of attacking the guard when the guard is vigilant:

say "'Ma'am, I have training in Jujitsu, Karate, Chow Mein, and Kung Fu. You do not want to mess with me,' he says in a monotonous tone."

Check smelling the guard when the setting of the thermostat is warm:

ignore the block smelling rule.

Carry out smelling the guard when the setting of the thermostat is warm:

say "He smells sweaty."

Instead of pulling the guard when the guard is vigilant:

say "You are not likely to get the guard off his post with physical force, him being almost twice your size."

Instead of showing a drink to the guard when the guard is vigilant:

if the setting of the thermostat is cool:

say "'Thank you ma'am, but this thing is keeping me quite refreshed,' the guard says and points at the ventilation duct.";

otherwise if the noun is masked alcohol:

say "'Thank you, ma'am!' the guard says and grabs the glass. He takes a sip and gives it promptly back. 'Sorry, ma'am, I can't drink alcohol on the job,' he says.";

otherwise if the noun is alcoholic:

say "He gives the drink a longing look, smacking his dry lips. 'Thank you, ma'am, but I have to stay vigilant,' he says.";

otherwise if the noun is spiced:

say "'Thank you, ma'am! I appreciate this,' the guard says and takes the glass. He empties it in a single draw.[paragraph break]'This is... strange...' he says, and falls straight on a couch. You're worried for a moment that he might be more than just asleep, but you can see him breathing peacefully in his slumber.";

now the guard is asleep;

award 1 point for "drugging the guard";

change the hint list of the sofas to the table of sofa hints;

change the hint list of Britney to the table of Britney hints;

reset the noun;

repeat with X running through distant things in the VIP lounge:

now X is near;

otherwise:

say "The guard empties [the noun] in a single gulp. 'Thank you ma'am! That did the trick.'";

reset the noun.

Instead of searching the guard when the guard is vigilant:

say "'Ma'am, if anyone here is doing any frisking, it is going to be me,' the guard says."

Instead of searching the guard when the taser is not handled:

say "In the guard's pocket you find a taser.";

now the player carries the taser.

Instead of searching the guard:

say "You don't find anything else."

Instead of insulting the guard:

if the guard is vigilant:

say "'[Lame insult]!'[paragraph break]'That won't get you in, ma'am,' he says.";

otherwise:

say "'[Lame insult]!'[paragraph break]Ha! He doesn't respond. Got him speechless!"

Instead of entering the guard when the guard is asleep and the player's command includes "sit":

say "Even if he's lying on the sofa, that doesn't make him a cushion."

The hint list of the guard is the table of guard hints.

Table of guard hints

hint

"The guard takes his work seriously."

"You can't get in the VIP area without a pass as long as the guard is there."

"You need to get the guard out or somehow disable him."

"Some knock-out drops would do the trick."

"Find a drugged drink and give it to the guard."

"The guard needs to be thirsty before he accepts drinks."

"He won't have anything alcoholic, either."

"Did you notice what's directly above him?"

"You need to get the heating duct to blow hot air."

"There's a thermostat by the entrance. Set it to warm."

"When the heating duct is blowing hot air and you have a non-alcoholic drink that has been drugged with knock-out pills, give it to the guard."

"Remember to search him when he's out cold."

"When the guard is out of the way, he's of no further help."

Chapter Ventilation duct

The ventilation duct is scenery in the VIP lounge. It is distant. The description is "The ventilation duct on the ceiling blows [setting of the thermostat] air down[if the guard is vigilant] straight on the guard[end if][if the guard is vigilant and the setting of the thermostat is warm]. He looks quite uncomfortable[otherwise if the setting of the thermostat is cool]. The VIPs get all the nice things[end if]."

Before entering the ventilation duct:

say "You don't have any motor oil." instead. [if you're wondering what this means, it's just an obscure reference to one of my earlier works]

Understand "heating/cooling" and "air" and "vent" and "hot/warm" and "cold/cool" as the ventilation duct.

Chapter Taser

The taser is a thing. The description is "The hand-held stunning device looks impressive." Understand "stunning" and "device" and "tazer" and "hand held" and "hand-held" as the taser.

Instead of switching on the taser:

say "The taser will work automatically if you zap someone with it."

Check zapping something with the taser:

if the noun is a person:

say "[The noun] do[es]n't deserve zapping." instead;

otherwise:

say "Zapping [the noun] wouldn't do much good. It's only effective against people." instead.

The hint list of the taser is the table of taser hints.

Table of taser hints

hint

"The taser is handy for tasering people."

"Who would you most like to zap?"

"[The Sleaze] is the optimal target."

"Zapping [the Sleaze] isn't effective when he's just sitting there in the bar. You have to wait until the taser really comes in handy."

Chapter VIP pass

The VIP pass is a card. The description is "The pass allows for the person holding it to enter the VIP lounge. Not that it's that useful now when the lounge guard is out of the picture."

Understand "card" as the VIP pass.

Instead of showing the VIP pass to the Sleaze:

say "[one of]'Care for a pass for the VIP lounge?' you ask and wave the pass in front of [the Sleaze]. 'Would I!' he says delighted. 'The rich and the idle are just waiting for a knight in white armor to come save them from boredom,' he says, grabs the pass and heads to the lounge.[or]'Well,' [the sleaze] says when you offer the pass to him. 'Things really didn't go that well the last time, but I guess it won't hurt to keep trying.' He takes the pass and goes back to the VIP lounge.[stopping]";

now the VIP-Sleaze is in the VIP lounge;

remove the Sleaze from play;

remove the VIP pass from play.

Instead of showing the VIP pass to the Sleaze when the bubblegum is part of the VIP pass:

say "'I appreciate the offer,' [the Sleaze] says, 'but... uhm... there's some goo on it.'"

The hint list of the VIP pass is the table of VIP pass hints.

Table of VIP pass hints

hint

"In theory the VIP pass is useless since the guard is out of the way."

"Not everybody knows that the guard isn't there, so giving the pass to them might have them go there."

"Give the VIP pass to [the Sleaze]."

Chapter Britney

Britney is a woman in the VIP lounge. "Britney, the bimbo girlfriend of Gus, sits on a couch [if drunk]swaying from side to side[otherwise]looking bored[end if]." The description is "Britney and Gus are a perfect match. He's full of hot air and her head is full of air. She sits there in her tiny tiny skirt and top looking like a circus clown in her face plastered with makeup.[if Britney is drunk][paragraph break]She looks like she's a bit tipsy."

Britney can be hostile or amicable. Britney is hostile. Britney is distant.

Britney can be sober or drunk. Britney is sober.

Understand "bimbo" and "girlfriend" and "gf" and "brit" as Britney.

Table of Hostile Britney Conversation

quip

"'Hello, Britney.'[paragraph break]'Hel-lo, Jen,' she says without bothering to look at you."

"'How did you get into the VIP lounge?'[paragraph break]'That's like the most stupidest question e-ver,' she says with her annoying nasal voice. 'I'm like the main star's gee ef, and you very well know it.'"

"'Wanna talk about Gus?'[paragraph break]'Like, why should I want to?' she gushes. 'Gus gets like really pissed off if I accidentally go telling something I shouldn't. I usually don't, not unless I'm like totally wasted, but still.'"

"'C'mon, Britney. Let's talk about Gus, only for a little while. I'm... uh, really curious about him.'[paragraph break]'No way! I only talk about my boyfriend with my [italic type]friends[roman type]. And we're not friends, Jen.'"

Table of Amicable Britney Conversation

quip

"'So, now that we're friends, how about we talk about, say, Gus?'[paragraph break]'I don't know, Jen. Can't we talk about something more important, like makeup or something?'"

"'No, really, let's talk about Gus. What's his mother like?'[paragraph break]'Yeah, uh... Well, I shouldn't really like talk about that. Gus has said that it might hurt him, somehow. I dunno.'"

"'C'mon, Britney. Are'nt we friends?'[paragraph break]'Yeah, I guess so, but Gus says I like really shouldn't. There was this like totally embarassing thing when I got like drunk and kinda told people all these embarassing things. Gus got like really angry.'"

The conversation table of Britney is the table of Hostile Britney Conversation.

Instead of insulting hostile Britney:

say "'[Lame insult].'[paragraph break]'What a totally awful thing to say! You're really not my friend!' she gasps."

Instead of insulting amicable Britney:

if Britney is drunk:

say "'[Lame insult].'[paragraph break]'That's.. uh.. what did you say about my momma?' she stammers.";

otherwise:

say "'[Lame insult].'[paragraph break]'That's not a nice thing to say, Jen,' she says. 'But I'll let it like go because we're friends.'".

Check showing a drink to Britney when Britney is hostile:

say "'I only take drinks from my [italic type]friends[roman type],' Britney sneers. 'Gus says it's dangerous to accept drinks from strangers.'" instead.

Check showing a spiced drink to Britney:

say "Better not. She's no use passed out." instead.

Instead of showing a drink to Britney when Britney is sober and Britney is amicable and the noun is spiced:

say "Better not. She's no use passed out."

Instead of showing a drink to Britney when Britney is sober and Britney is amicable:

if the noun is masked alcohol:

say "'Thanks Jen! It's, like, cola? Right?'[paragraph break]'Uh, yeah. It's like cola,' you say.[paragraph break]'Ok, great!' She takes a gulp of the drink. 'You know, Jen, we're like, we're like, we're like the BESTESTEST frriends EVER!' she stammers. Worst. Alcohol tolerance. Ever.";

now Britney is drunk;

reset the mix;

otherwise if the noun is the tonic or the noun is the mix and the color of the mix is clear and tonic is mixed:

say "'Is it, like, water? That's [italic type]so[roman type] lame,' Britney sneers.";

otherwise if the noun is cola:

say "'Oh thanks, Jen! You're, like, a real good friend,' she says and takes the drink.";

reset the cola;

otherwise if the noun is alcoholic:

say "'I can't like drink any booze, Jen! Gus says I tend to blurt out stuff I shouldn't say when I'm drunk,' Britney says.";

otherwise if the noun is the mix and cola is mixed and tonic is mixed:

say "'What is that? Did they like run out of cola and filled the rest of the glass with water?' Britney sneers.";

otherwise:

say "'No thanks, Jen,' Britney says.". [this should never fire but better make sure it says something]

Instead of talking to Britney when Britney is drunk:

say "She seems to be busy talking, not really paying attention to who is listening. It's unlikely she'll blurt out any more gems."

Instead of talking to Britney when Britney is drunk for the first time:

say "'Oh, hi Jen! We're just the bestest bee ef efs, aren't we?' She speaks in fast and short segments, like a machine gun firing bursts of stupid. 'I should like totally do your hair sometime, do you know this totally awesome conditioner...'

'...and then I was totally like, [']Like, are you like totally...[']'

'...then we went for a burger and I said like, [']You know like how many calories those things have like?[']...'

'...and we went to the aquarium, and Gus's mom just had to drag along...'

What? You snap out of the torpor your brain had induced to prevent any permanent damage. 'What's that about Gus's momma?'

'Yeah, it was kinda drag but kinda funny too when she accidentally slipped into the dolphin pool. But scary too. Anyway, I had this totally cool sweater on I bought the other day and...'

That's it! That would like totally work! Er... gah, must get out of here before your wits are completely corrupted.";

award 3 points for "learning about Gus's momma's mishap at the aquarium";

get inspired by "whale".

The hint list of Britney is the table of no access hints.

Table of Britney hints

hint

"Britney is Gus's girlfriend. She might have good information on Gus."

"Unfortunately she refuses to talk to you because you're not her friend."

"You should gain her trust somehow."

"Maybe if you saved her from the amorous attempts of someone she doesn't care for."

"You should get [the Sleaze] to the VIP lounge."

"[The Sleaze] doesn't know the guard is out, so you have to find a VIP pass for him."

"When [the Sleaze] is hitting on britney, find a way to get rid of him."

"Having Vincent beat him up isn't good enough because Britney won't believe you asked Vincent to do that."

"You need to find a taser to get rid of [the Sleaze]."

"When you've gained Britney's friendship, you need to get her to talk."

"She takes drinks from you now, but she won't take anything alcoholic."

"Maybe give her something that looks like it's not alcoholic but actually is."

"Mix cola with something alcoholic and give it to Britney, then talk to her."

Volume III - Scenes

Part The Whispering Stranger

The Whispering Stranger is a scene. The Whispering Stranger begins when the player is in the Dance floor and debugging is false.

When the Whispering Stranger begins:

say "It looks as if somebody in a dark corner table to the southeast is making a 'come here' gesture.";

now the mysterious stranger is familiar;

the mysterious stranger repeats his call in 4 turns from now.

Instead of going when the Whispering Stranger is happening and the noun is not southeast:

say "You feel intrigued by the mysterious stranger in the southeast corner. Maybe you should check him out before exploring the rest of the club."

Instead of moving to when the Whispering Stranger is happening and the noun is not the Dark corner and the noun is not the Stage:

try going south. [any direction will do, just so that it triggers the rule above.]

Before going north when the Whispering Stranger is happening:

say "You don't feel ready to challenge Gus again." instead.

Before moving to the Stage when the Whispering Stranger is happening:

try going north instead.

At the time when the mysterious stranger repeats his call:

if the Whispering Stranger is happening:

say "You see the mysterious stranger in the southeast corner table waving again for you to come closer.";

the mysterious stranger repeats his call in 4 turns from now.

The Whispering Stranger ends when the player is in the Dark Corner.

Part The Shadowy Stranger

The Shadowy Stranger is a scene. The Shadowy Stranger begins when the player is in the Dark Corner and debugging is false.

Instead of talking to the mysterious stranger when The Shadowy Stranger is happening:

clarify "first sitting on the chair";

silently try entering the corner chair.

Instead of going when The Shadowy Stranger is happening:

say "The stranger is at the same time frightening and intriguing. You feel like running away but curiosity overcomes the feeling. You can't leave before hearing what he has to say."

Before moving to when The Shadowy Stranger is happening:

try going north instead. [triggers the rule above]

After entering the corner chair when The Shadowy Stranger is happening:

say "'You blew it up there, kid,' the stranger says. 'Blew it big time.'

You feel your cheeks getting red. 'Oh yeah? Who are you to judge?'

You're about to get up but he raises his hand. 'I speak from experience. But don't worry, kid, I see you have potential. The game is not over yet. I can help you win the championship. If you're up for it.'

'Who... Who are you?'

He leans forward into the spotlight and reveals his face. An eyepatch covers the old man's right eye and a wide scar runs below it, from the right temple to the left side of his neck. You jolt backwards, not because of the grotesque sight, but because you recognize him.

It's Joe Mahma.";

remove the mysterious stranger from play;

now Joe Mahma is in the Dark Corner;

now Joe Mahma is familiar;

have the parser notice Joe Mahma. [changes "him" to refer to Joe instead of the mysterious stranger]

The Shadowy Stranger ends when Joe Mahma is in the Dark corner.

Part Joe Mahma introduces himself

Joe Mahma Introduces Himself is a scene. Joe Mahma Introduces Himself begins when The Shadowy Stranger ends.

When Joe Mahma Introduces himself begins:

Joe Mahma continues in 1 minute from now.

At the time when Joe Mahma continues:

let consented be true;

say "'Joe Mahma! No way!' you gasp.

'I see you know me, kid. Good to know somebody still does.'

Of course you know who Joe Mahma is. Everybody knows Joe Mahma. He's a living legend, the infamous grandmaster of Yo Momma insult battles.

'Look, kid, you want my help or not?'[paragraph break]>";

if not the player consents:

say "'Are you sure, kid? You think you can make it by yourself?'[paragraph break]>";

if the player consents:

say "'Alright, then. I like your spirit. That's how I did it in my days, with hard work, with nobody holding my hand. Good luck.'[paragraph break]With those words he stands up and walks away.[paragraph break]Over the next few weeks it becomes clear that you don't have what it takes to deal with the competition. Soon you forget Yo Momma battles and move on with your life.";

let consented be false;

end the game in death;

if consented is true:

say "'Ok then. Listen carefully. I know and you know you're not ready to take Gus head on. But here's the thing. A sharp tongue is all good and fine but when you really want to knock your opponent off their feet you have to strike hard. And nothing hurts more than truth. You follow me?'

'Not really,' you confess.

'Pay attention now! Do some reconnaissance. Dig out some facts and use them against him. When you have enough information, just think of what you have learned and the right insult will come to you. Got it?'

'Snoop around for embarassing facts, draw inspiration from them. Got it.'

'That's the spirit! Go for it, kid!'".

Before going or moving to or exiting or getting off when Joe Mahma Introduces Himself is happening:

say "[one of]You can't just leave now when you have the chance to talk with the Master himself. It's Joe Mahma for crying out loud![or][run paragraph on][stopping]" instead. [for some reason this showed up twice sometimes. one of..stopping prevents that.]

Before examining the eyepatch when Joe Mahma Introduces Himself is happening:

say "Right now is not a good time to focus on that." instead.

Talking to Joe Mahma is introductory ignoring.

Listening to Joe Mahma is introductory ignoring.

Listening to the dark corner is introductory ignoring.

Waiting is introductory ignoring.

Before introductory ignoring while Joe Mahma Introduces Himself is happening:

do nothing instead.

Joe Mahma Introduces Himself ends when the time since Joe Mahma Introduces Himself began is 2 minutes.

When Joe Mahma Introduces Himself ends:

now Norbert is in the Dance floor.

Part Fight on the Dance Floor

Fight on the Dance Floor is a scene. Fight on the Dance Floor begins when Vincent is not in the Arcade corner.

Fight on the Dance Floor ends when the setting of the thermostat has been warm for 3 turns.

When Fight on the Dance Floor begins:

remove the hints from the bouncer.

When Fight on the Dance Floor ends:

if the location is the dance floor:

say "The bouncer manages to finally separate Vincent and Norbert from each other. Vincent goes back to his game and the bouncer goes to watch the door. Norbert stays there, looking miserable and bruised";

otherwise:

say "Looks like the commotion on the dance floor is dying down";

if the location is the Arcade corner:

say ". Vincent comes back, looking angry as a bee-stung bear, and returns to his arcade game";

if the location is the Entrance:

say ". The bouncer comes back to watch the door";

say ".";

now the bouncer is in the Entrance;

now Norbert is in the Dance floor;

now Norbert is beaten;

now Norbert is recently beaten;

now Vincent is in the Arcade corner;

now the lens is hidden;

now the glasses are broken;

now the conversation table of Norbert is the table of Missing Lens Conversation;

remove the commotion from play.

The commotion is a plural-named, familiar person. Understand "people" and "vincent" and "norbert" and "bouncer" and "fight/quarrel" as the commotion. The initial appearance is "Vincent is roughing up poor Norbert and the bouncer is trying to separate the two with little success." The description is "'You take back what you said about my momma!' Vincent roars.[paragraph break]'I do believe I have not mentioned such atrocities that you speak of about your maternal parent,' Norbert declares.[paragraph break]'Stop talking that gibberish, dude! Yer makin['] me dizzy!' Vincent screams."

Instead of talking to the commotion:

say "Talking is futile -- none of them is listening to a word."

Instead of insulting the commotion:

say "'All of yo's mommas are fat. And stupid.'[paragraph break]Your insult goes to waste. They are too busy to listen anything you say."

Every turn when the commotion is in the location and a random chance of 1 in 6 succeeds:

say "[one of]The bouncer tries to pull Vincent away from Norbert but fails miserably.[or]Vincent wraps his left arm around Norbert's head and rubs his scalp with his right fist.[or]Vincent holds Norbert's hand and makes him slap himself. 'Why are you hitting yourself? Why are you hitting yourself?'[or]'Come on now boys, you're both getting yourselves banned from here if you don't stop right now,' the bouncer tries to say.[at random]".

Part Too Hot for Wearing a Shirt

Too Hot for Wearing a Shirt is a scene. Too Hot for Wearing a Shirt begins when the Fight on the Dance Floor has ended and the time since the Fight on the Dance Floor ended is 2 minutes.

Too Hot for Wearing a Shirt ends when Gus is not wearing the sweater.

Every turn when the Too Hot for Wearing a Shirt is happening and the location is the Artist hangout:

say "'Man, it's really hot in here, dontcha think?' Gus says. His posse nods in unison, competing who can agree the most. Assflies. He takes his sweater off and hangs it on the back of a nearby chair.";

award 1 point for "turning the heat up";

now the sweater is on the hangout-chair;

remove the hints from Gus;

change the hint list of the sweater to the table of removed sweater hints;

change the hint list of the tag to the table of removed sweater hints.

Every turn when the setting of the thermostat is warm and Too Hot for Wearing a Shirt has ended and the guard is asleep:

if the location is the Entrance:

say "'Phew. It's really hot in here,' the bouncer says and glances on the thermostat. 'Hey, who's been meddling with this?'

He turns the heat down and returns to his post.";

now the setting of the thermostat is cool.

Part Inappropriate Music

Inappropriate Music is a recurring scene. Inappropriate Music begins when the current selection of the jukebox is ass. Inappropriate Music ends when the current selection of the jukebox is not ass.

When Inappropriate Music begins:

say "'What the... Who changed the music[one of]? I thought the new label made it perfectly clear you [italic type]don't[roman type] play that crap here!' Ralph[or]?' Ralph[stopping] shouts as he gets up from the chair. 'Get away from the jukebox, you twerp!'";

now Ralph is distracted;

if the jukebox is not jammed:

ralph changing the music happens in one turn from now;

otherwise:

remove hints from bubblegum;

award 1 point for "distracting Ralph".

At the time when Ralph changing the music happens:

if the bubblegum is part of rap:

if the location is the location of Ralph:

say "Ralph inserts a coin and tries to push the rap button, but the button is stuck. He pushes the r&b button instead and the music changes.";

now the current selection of the jukebox is r&b;

otherwise:

if the location is the location of Ralph:

say "Ralph puts a coin into the jukebox and pushes the rap button.";

now the current selection of the jukebox is rap.

Flavor text rule when Inappropriate Music is happening and the jukebox is jammed and the location is the location of Ralph:

if the location is the location of Ralph:

say "[one of][run paragraph on][or]'Hey! What's wrong with this stupid machine?' Ralph swears and pounds on the jukebox buttons.[or][one of]'Stupid piece of junk,' Ralph says.[or]'Work, damn it!' Ralph screams and kicks the jukebox.[or]'Why...can't...this...junk...work!' Ralph says frustrated.[or]Ralph has a fit and pounds himself instead of the jukebox.[or][run paragraph on][or][run paragraph on][at random][stopping]".

When Inappropriate Music ends:

if the jukebox is jammed:

say "Ralph finally gets the bubblegum scraped off and gets the music changed. He comes back to his seat, steaming from the ears.[line break]";

now the current selection of the jukebox is rap;

remove bubblegum from play;

otherwise if the location is the location of Ralph:

say "Ralph returns from the jukebox.";

now the current selection of the jukebox is rap;

otherwise:

say "The music changes into [current selection of the jukebox].";

if the satchel is open:

if the location is the location of Ralph:

say "[line break]'Hey, are you messing with Gus's bag? Get out of here, twerp!' Ralph says and pushes you away. He closes the bag and sits on the chair.";

now the satchel is closed;

now Ralph is alert.

Instead of doing something to the jukebox when Inappropriate Music is happening:

say "'Stay away, twerp,' Ralph says and shoves you away."

Instead of doing something to a thing which is enclosed by the jukebox when Inappropriate Music is happening:

say "'Stay away, twerp,' Ralph says and shoves you away."

Test satchel with "test gum/hall/put gum in ass/purloin coins/put coin in jukebox/push ass".

Part The Sleaze Finds a New Target

The Sleaze Finds a New Target is a recurring scene. The Sleaze Finds a New Target begins when the VIP-Sleaze is in the VIP lounge.

The Sleaze Finds a New Target ends when the VIP-Sleaze is not in the VIP lounge.

When the Sleaze Finds a New Target begins:

now Britney is scenery.

When the Sleaze Finds a New Target ends:

now Britney is not scenery.

A flavor text rule when the location is the VIP lounge and The Sleaze Finds a New Target is happening and the turn count is even:

choose a random row in the table of Sleaze hitting on Britney flavor texts;

say "[quip entry][line break]".

Table of Sleaze hitting on Britney flavor texts

quip

"'Hey there, sister. You look like you would need a man in your life,' [the Sleaze] suggests to Britney. 'Get lost creep,' Britney says."

"[The Sleaze] tries to wrap his arm around Britney but she slaps his hand away."

"'Hey, how about you come back to my place for some late night snack? I got something that just needs to be between your lips,' [the sleaze] says. 'Why don't you just get lost,' Britney screams."

"'My boyfriend is just about to come back,' Britney tries to convince [the Sleaze]. 'I bet he is,' [the Sleaze] says."

"[The Sleaze] inches closer to Britney, who moves the same amount away."

"'Wanna dance?' [the Sleaze] asks Britney. 'I would rather die,' Britney slings back."

"Britney throws a look at you that screams 'help me'."

"'Hey baby, wanna do the mambo? An['] I don't mean dancin['],' [the Sleaze] suggests to Britney. 'Why don't you, like, shoot yourself,' Britney hisses."

"[The Sleaze] says, 'Would you like to come to my place and see my bedroom ceiling?'[paragraph break]Britney makes a gagging noise."

"'Excuse me,' [the Sleaze] says to Britney. 'Is this the library? I'd like to check you out.'"

"'Why don't you make like a tree and get out of here,' Britney snaps at [the Sleaze]."

"[The Sleaze] says, 'I'd like to get into something more comfortable. You.' Britney slaps him."

"'Do you believe in love at first sight, or should I come back again?' [the Sleaze] asks. 'You can start by leaving,' Britney replies."

"'Nice outfit,' [the Sleaze] says to Britney. 'It'll look good on my bedroom floor.' She tries to tug her skirt hem lower with little success."

"'Wanna go camping?' [the Sleaze] asks Britney. 'You don't need to bring your own sleeping bag. Mine is big enough for two.' Britney buries her head in her hands."

"[']Get rid of him,['] Britney mouthes to you."

Instead of talking to Britney when the Sleaze Finds a New Target is happening:

say "You try to talk to Britney, but [the Sleaze] distracts her too much."

The VIP-Sleaze is a man. "[The Sleaze] sits on the couch with Britney who is doing her best to ignore him."

The description is "[The description of the Sleaze][paragraph break]He's currently working hard to have Britney notice him."

The printed name is "the Sleaze". The VIP-Sleaze is privately-named and proper-named.

Understand "sleaze" and "mcdouchebag" and "douchebag" and "douche" and "sleazeball" and "sleazebag" and "man" as the VIP-Sleaze.

Instead of talking to the VIP-Sleaze:

say "He's far too busy hitting on Britney to pay any attention to you."

Instead of attacking the VIP-Sleaze:

say "Jumping on the couch and wrestling with [the Sleaze] is a rather disturbing thought. You need some heavier tools for this situation."

Instead of zapping the VIP-Sleaze with the taser:

say "You pull the taser from your pocket. 'Well hello, beautiful,' [the Sleaze] says and turns to you. 'I was just talking with your friend here. I was thinking all three of us could go to my place and' *kZap* 'OH my dear GOD WHAT the' *kZap* 'that really HURTS' *kZap* 'no NOT THERE PLEASE' *kZap* *kZap*

[The Sleaze] staggers away, smoke rising from his head. His limbs twitch as he stumbles back to the bar.

'Oh wow, Jen. That's really sweet of you!' Britney stands up and gives you an awkward hug. 'I think we could be like really good friends, Jen!'";

remove VIP-Sleaze from play;

now Britney is amicable;

now the Sleaze is in the Bar;

remove the hints from the taser;

remove the hints from the VIP pass;

now the conversation table of Britney is the table of Amicable Britney Conversation;

award 1 point for "making friends with Britney".

Volume IV - Help

Book License

After printing the banner text, say "This game is free software. Type LICENSE for details or ABOUT for game info.[paragraph break]";

Help-license is an action out of world.

Understand "license" and "licence" and "lisense" and "lisence" and "copyright" and "terms" and "eula" as help-license.

Carry out help-license:

say "[license]";

To say license:

say "[line break]Copyright (C) 2010 Juhana Leinonen <[Juhana's email]>

Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated documentation files (the 'Software'), to deal in the Software without restriction, including without limitation the rights to use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of the Software, and to permit persons to whom the Software is furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.";

To say Juhana's email:

say "juhana";

say ".if";

say "@";

say "nitku";

say ".net".

Book About

Abouting is an action out of world.

Understand "about" and "info" and "help" as abouting.

Carry out abouting:

say "Hello. You are playing [italic type][story title][roman type]. It was initially made for the Newer New Year's Speed IF event, although the amount of work spent on this piece is substantially more than the traditional two hour speed-if limit.

A couple of words about playing. In addition to moving around using the standard compass directions you can move to locations just by typing their name, or by typing the name of a character in that location. You can get to the center of the club by commanding CENTER or just C. Type MAP to see all available locations.

To talk with other characters you can TALK TO and INSULT them. You can also SHOW things to them (GIVE is synonymous). SEARCH, LOOK UNDER and LOOK BEHIND are all mutually synonymous.

If you are new to interactive fiction and unsure of how to play, please see http://www.brasslantern.org/beginners/ for excellent guides and articles on the subject.

This is release number [release number]. Please check http://www.nitku.net/if/yomomma for updates before you start playing. Save games are unfortunately not compatible between different releases.

If you get stuck, you can find hints from the abovementioned web address. For feedback and other comments you can contact the author at [Juhana's email]. See CREDITS for a list of other contributors."

Crediting is an action out of world.

Understand "credits" as crediting.

Carry out crediting:

say "[italic type][story title][roman type] was designed and programmed by Juhana Leinonen.

Beta testers who uncovered a formidable amount of bugs and typos and provided invaluable feedback: Conrad, Jimmy Maher, Sarah Morayati, Poster, Matthew Spain, and Taleslinger.

Thanks to Taleslinger for organizing the speed-if event (and thus giving motivation to make the game) and to people at ifMUD for bad pickup lines. Special thanks go to the players at the ClubFloyd session -- where the game premiered -- for finding the first batch of bugs. For those interested the transcript can be read at http://www.allthingsjacq.com/intfic_clubfloyd_20100102.html."

Book Hints

Thinking about is an action out of world with past participle thought, applying to one visible thing.

Understand the command "think" as something new.

Understand "think about [any known thing]" as thinking about.

Understand "think [any known thing]" as thinking about.

Understand "think" as thinking about.

Understand the command "hint" as "think".

Table of generic hints

hint

"Remember to TALK TO everyone you meet. Some people might have more than one thing to say."

"It's useful to SEARCH everything for hidden things."

"The people in the club are the key to most puzzles. Consider what they could want or how they might act in response to your actions."

Carry out of thinking about nothing:

if we have thought about:

if the table of generic hints is not empty:

choose a random row in the table of generic hints;

say "[hint entry][line break]";

blank out the whole row;

otherwise:

say "You can THINK ABOUT things and people you have seen in order to get hints.";

otherwise:

say "For puzzle hints, you can THINK ABOUT different things and people you have seen. Each time you do this you will be given another hint towards the solution to a puzzle.

You can also THINK to get general tips and suggestions."

To print a hint from (hint-table - a table-name):

if hint-table is empty:

say "Nothing particular comes to mind.";

otherwise:

repeat with X running from 1 to the number of rows in the hint-table:

choose row X in the hint-table;

if there is a hint entry:

say "[hint entry] ([X]/[number of rows in hint-table])[line break]";

if X is not the number of rows in hint-table:

blank out the whole row;

break.

A thing has a table-name called hint list.

Carry out thinking about a known thing:

print a hint from the hint list of the noun.

Understand "think [text]" as a mistake ("You don't remember seeing any such thing.").

Table of no hints

hint

text

Table of no importance

hint

"[The noun] [is-are] of no importance."

To remove the/-- hints from (solved - a thing):

change the hint list of the solved to the table of no hints.

Book Interface tips

After going when Joe Mahma Introduces Himself has ended and we have not moved to for the second time:

say "[italic type](In addition to using the compass directions you can move around the club by simply typing the name of the location where you want to go, or a name of a person in the location. You can also see the list of all locations by commanding MAP.)[line break][roman type]";

continue the action.

Book Comments - Not for release

Commenting is an action out of world applying to one topic.

Understand "* [text]" and "note [text]" as commenting.

The last comment turn is a number that varies. The last comment turn is 0.

Carry out commenting:

change the last comment turn to the turn count.

Report commenting:

if the player's command includes "ha" or the player's command includes "heh":

say "[one of]Yeah, that's funny.[or]Heh, yeah.[or]Comedy gold.[or]That's [a random number between 10 and 90] % more funny in this version.[at random]";

otherwise:

say "[one of]I see.[or]You have a point there.[or]That's true.[or]Yeah, well, ok.[or]Mind you, I was drunk when I wrote that bit.[or]Uh, maybe it's an interpreter issue?[or]Should be an easy fix.[or]It's on purpose! No wait, it's not.[or]Ah.[or]Oh well.[or]Can't argue with that.[or]Really?[at random]".

Check commenting when the last comment turn is the turn count and the last comment turn is not 1000:

say "Yo comment's so fat it needs two rows.";

change the last comment turn to 1000;

stop the action.

Volume V - Development - Not for release

Book Winning

Winning is an action out of world.

Understand "win" as winning.

Carry out winning:

win the game.

Book Object Response Tests

Procedural rule:

ignore the test looking under rule;

ignore the test cutting rule;

ignore the test swinging rule;

ignore the test rubbing rule;

ignore the test waking rule;

ignore the test squeezing rule;

ignore the test burning rule;

ignore the test tasting rule;

ignore the test tying to rule;

ignore the test waving rule.