Raising the Flag on Mount Yo Momma — 26 of 87

Chapter Moving to

Moving to is an action applying to one visible thing.

Understand "go to [any room]" as moving to.

Understand "go to [any goable person]" as moving to.

Understand "go [any room]" as moving to.

Understand "go [any goable person]" as moving to.

Understand "move to [any room]" as moving to.

Understand "move to [any goable person]" as moving to.

Understand "[any goable person]" as moving to.

Understand "[any room]" as moving to.

[

Understand "[any move-to-object thing]" as moving to.

Definition: a thing is a move-to-object if it is a room or (it is a known person and it is in a room).]

Definition: a person is goable if it is known and the location of it is a room.

[going to the dance floor is a bit problematic because the command DANCE interferes]

Understand "dance [any dancy room]" as moving to.

Definition: a room is dancy if it is the dance floor.

Understand "[text]" as a mistake ("[unknown command]").

To say unknown command:

say "That verb is not used in this game.[run paragraph on][line break]";

if the location is the location of Norbert and a random chance of 1 in 15 succeeds:

say "[line break]Norbert asks, 'YLAC?'[run paragraph on][line break]".

Check moving to when the location is the noun:

say "You are already there." instead.

Check moving to when the location is the location of the noun:

say "[The noun] is right here." instead.

Check moving to when the noun is not a room and the location of the noun is not a room:

say "You can't go to [the noun] right now." instead.

Carry out moving to:

if the noun is a room:

move the player to the noun;

otherwise:

move the player to the location of the noun.

Moving to is traveling.

Going is traveling.