Sparkle — 103 of 108

Part 4 - Eating

Chapter 1 - Sausage

To decide whether the dog can reach the sausage:

if the sausage is enclosed by the player: [1]

decide no;

if the dog is in the holder of the sausage:

decide yes;

if the dog is not in the location of the dog: [2]

decide no;

if the location of the dog is the location of the sausage:

decide yes;

decide no.

Every turn when the dog can see the edible sausage and the dog can reach the sausage:

if the player can see the dog:

say "The dog notices the sausage and then gobbles it up in one bite. He licks his lips happily.";

feed the dog.

Every turn when the dog can see the edible sausage and not the dog can reach the sausage and the player can see the dog and the player is not carrying the sausage and the dog is not in the lowered left dumbwaiter and the current action is not changing into:

say "The dog looks at the sausage and drools."

Check giving the inedible sausage to the dog:

say "The dog sniffs the sausage, but turns his head away. It's in too bad shape for even the dog to eat." instead.

Instead of giving the edible sausage to the dog:

say "[We]['re] barely able to get [our] fingers out the way as the dog snatches the sausage. He gulps it down hungrily and licks his lips happily.";

feed the dog.

Instead of showing the sausage to the dog:

try giving the sausage to the dog.

Instead of throwing the sausage at the dog:

say "(giving the sausage to the dog)[command clarification break]";

try giving the sausage to the dog.

To feed the dog:

say line break;

if the player can see the dog:

say "The dog's mood seems to change. He doesn't bark anymore and looks at us, panting.";

otherwise:

say "[We] can't hear the dog barking anymore. Maybe he found the sausage?"; [3]

now the dog is satisfied;

remove the sausage from play.