Escapade!
An interactive fiction by Juhana Leinonen (2008) - the Inform 7 source text
Contents
Previous
Next
Complete text
The Skindude multitool is a conversable thing. It can be mysterious, known but unopened, or turned into screwdriver. It is mysterious. It is useful. The description is "[if the multitool is known but unopened]It's a slightly rusted Skindude[tm] multitool, with all sorts of useful tools inside.[otherwise]It's a rusted piece of crap, that's what it is. The screwdriver part looks still somewhat functional." The printed name is "squarish metallic object".
Understand "free" and "sample/samples" and "tool/tools" and "halves" and "rust/rusted" and "squarish/square" and "metallic/metal" and "object" as the multitool.
Understand "screwdriver" and "screw driver" and "driver" and "hinge" as the multitool when the multitool is turned into screwdriver.
Understand "knives/knife" and "file/files" as the multitool when the multitool is known but unopened.
The creature response of the Skindude multitool is "[if the cell does not enclose the multitool]'The [']free gift['] was just a broken piece of crap!' you exclaim.[paragraph break][c]Let's not forget that a) it was [italic type]free[roman type] and b) it did get you out of here, didn't it? Too bad they had to bring you back in,[c] the creature replies a bit annoyed.[otherwise if the multitool is turned into screwdriver]'It's not much of a multitool as it is,' you reclaim[one of] when the plier part falls of the Skindude[tm] and disintegrates into rust particles as it hits the floor[or][stopping]. 'What, you want your money back? Sheesh, some customers,' it mutters under its breath.[otherwise]'Uh... What is it?' you ask.[paragraph break]'What is it[interrobang] What is it, he asks. Ha ha ha... what is it...' It coughs and says nothing more."
The guard response of the Skindude multitool is ""
Instead of discussing with the creature about the Skindude multitool when the Skindude multitool is not handled:
say "'So, what's the free sample?' you venture.[paragraph break]'The free sample, eh?' [the creature] says and flashes a smile. 'The minute I saw you I said to myself [']H.R., there is a man who goes to the supermarket just for the free taste samples.[']' It reaches for the sack and pulls out a squarish metallic object which it hands to you. 'Here ya go, sport. Knock your teeth out.'";
now the player carries the Skindude multitool;
stop the action.
Understand "knock my/your teeth out" as a mistake ( "[if the creature is present][c]Figuratively, monkey boy! Figuratively!' [the creature] exclaims.[otherwise]That might hurt." ).
Instead of examining the Skindude multitool for the first time:
say "After closer inspection the squarish metallic object turns out to be a slightly rusted Skindude[tm] multitool. It has two hollow halves connected with a hinge on one end. The halves can be opened to reveal knives, files, pliers and other tools inside. Excellent.";
now the printed name of the multitool is "Skindude[tm] multitool";
now the multitool is known but unopened.
Before opening the mysterious multitool:
say "You take a closer look before handling the object any further. [run paragraph on]";
try examining the multitool;
Before unscrewing something with the multitool:
if the multitool is not turned into screwdriver:
say "(first opening [the skindude multitool])[command clarification break]";
try opening the multitool;
continue the action.
Before unscrewing the doorhinges when the multitool is not turned into screwdriver:
if the player can see the multitool:
if the player is not carrying the multitool:
say "(first taking and opening [the skindude multitool])[command clarification break]";
silently try taking the skindude multitool;
otherwise:
try unscrewing the doorhinges with the multitool instead;
try opening the multitool;
continue the action.
Before opening the known but unopened multitool:
now the multitool is turned into screwdriver;
say "You pull the halves apart and the Skindude[tm] opens with a creak. A swarm of rust flakes flies from the hinges. Looks like almost everything inside is rusted through; the only tool that looks even remotely useful is the screwdriver.";
stop the action.
Instead of opening the turned into screwdriver multitool:
say "It's already open." instead.
Instead of opening the multitool:
do nothing. [I don't get it, but this fires up every time as well as the previous ones.]
Instead of closing the multitool:
say "It's already closed.".
Instead of closing the turned into screwdriver multitool:
say "It seems to be stuck open. Forcing might break it even more."
To say tm:
if unicode 8482 is supported:
say "[unicode 8482]";
otherwise:
say "(tm)";