Escapade!
An interactive fiction by Juhana Leinonen (2008) - the Inform 7 source text
Contents
Previous
Next
Complete text
The electrical wire is in the cell. It is scenery and middle. It can be fixed to the ceiling, pulled out or boobytrapping the door. It is fixed to the ceiling. The description is "[if the electrical wire is fixed to the ceiling]The wire hangs from the ceiling from a fragile looking attachment and leads to the cross section of the ceiling and two walls.[otherwise if the electrical wire is pulled out]The wire curls up in one corner and runs up to the cross section of the ceiling and two walls.[otherwise] The wire runs from the ceiling to the keyhole on the cell door."
Understand "socket" as the electrical wire when the cell is dark.
Instead of taking the electrical wire:
try pulling the electrical wire.
Instead of looking under the electrical wire:
say "There's the floor under it.".
Instead of searching the electrical wire:
say "There's nothing more to it.".
Instead of switching on the electrical wire:
say "There's no power switch in the cell.".
Instead of switching off the electrical wire:
say "There's no power switch in the cell.".
Instead of touching the electrical wire:
say "*kZAP*
The room soon stops spinning and you can see again. You smell something burning.[if the creature is present][one of][paragraph break][question intelligence][or][stopping]".
Instead of pushing the electrical wire when the electrical wire is fixed to the ceiling:
if the light bulb is a part of the electrical wire:
try pushing the light bulb;
otherwise:
say "You give it a small push and the wire swings back and forth a few times.".
Instead of swinging the electrical wire:
try pushing the electrical wire.
Instead of pulling the electrical wire when the light bulb is a part of the electrical wire:
try pulling the light bulb.
Instead of climbing the electrical wire when the electrical wire is pulled out:
say "It's too thin to climb. And there wouldn't be anything there to climb to anyway.".
Instead of climbing the electrical wire when the electrical wire is fixed to the ceiling:
if the light bulb is a part of the electrical wire:
if the light bulb is lit:
say "You try to climb the wire, first holding on to the bulb's socket and pulling yourself upward. The wire can't take your weight and it snaps, leaving you with the light bulb and its socket.
Miraculously enough the bulb is still lit even when it's not connected to anything[if the creature is present]. [c]Hmm,' H.R. muses[end if].";
now the player carries the light bulb;
otherwise:
say "You try to climb the wire, first holding on to the bulb's socket and pulling yourself upward. The bulb comes off almost as soon as you touch it. Apparently it wasn't screwed in all the way.";
now the player carries the light bulb;
otherwise:
try pulling the electrical wire.
Instead of tasting or eating the electrical wire:
say "Wondering if the wire [one of][or]still [stopping]has any power, you touch it with your tongue.
*kZAP*
'Ih HOEH hae oheh!' you discover.[if the creature is present] [question intelligence] [the creature] wonders.[end if]";
now the tongue is numb.
Instead of pulling the electrical wire when the light bulb is not part of the electrical wire:
if the electrical wire is fixed to the ceiling:
say "The hook that was holding the wire up in the ceiling breaks and the wire comes off. It now runs straight down from the ceiling corner and curls up in the floor.";
now the electrical wire is pulled out;
now the electrical wire is by the door;
remove the wire-attacher from play;
otherwise if the electrical wire is boobytrapping the door:
say "You pull the wire out from the keyhole.";
now the electrical wire is pulled out;
now the electrical wire is by the door;
otherwise:
say "It won't come out any further.";
Before inserting the electrical wire into the keyhole when the celldoor is insulated:
if the creature is present:
say "[c]That's no use anymore,[c] [the creature] says. [c]They coated the keyhole with rubber while you were away.[c]";
otherwise:
say "There seems to be a thin layer of rubber inside the lock. The same trick won't work anymore.";
stop the action;
Instead of inserting the electrical wire into the celldoor:
try inserting the electrical wire into the keyhole instead.
Instead of tying the electrical wire to the celldoor:
try inserting the electrical wire into the keyhole instead.
Instead of tying the electrical wire to the keyhole:
try inserting the electrical wire into the keyhole instead.
[
The take object before inserting it into rule is not listed in any rulebook.
The can't insert what's not held rule is not listed in any rulebook.
]
Before inserting the electrical wire into the keyhole when the light bulb is not part of the electrical wire and the cell is not dark:
if the celldoor is insulated:
try tying the electrical wire to the keyhole;
otherwise if the electrical wire is boobytrapping the door:
say "You make sure the wire is securely inside the keyhole.";
otherwise:
say "You tuck the live end of the wire into the keyhole.[if the creature is present][one of][line break][c]Aww, that's just nasty,' [the creature] says.[or][stopping]";
now the electrical wire is boobytrapping the door;
stop the action.
To zap the guard:
mark the escape down as "boobytrapping the door";
now the celldoor is insulated;
now the electrical wire is pulled out.
Test wire with "get lamp/pull wire/attach wire to door".