Escapade!
An interactive fiction by Juhana Leinonen (2008) - the Inform 7 source text
Contents
Previous
Next
Complete text
A thing can be a conversable. A thing is usually conversable.
A thing can be conversed or unconversed. A thing is usually unconversed.
Definition: A thing is discussable if it is a conversable or it is known.
Understand the command "ask" as something new.
Understand the command "tell" as something new.
Understand the command "say" as something new.
A thing has some text called creature response. The creature response of a thing is usually "".
A thing has some text called guard response. The guard response of a thing is usually "".
To say self-talking:
say "You discuss the subject with yourself for a while."
To say inanimate-talking:
say "'Hello there, [noun],' you say.[if the creature is present][one of][line break][question intelligence] [the creature] says.[or][stopping][end if]"
Discussing with it about is an action applying to two visible things.
Discussing with something about something is unktonking. [this just means we don't move towards an object before we talk about it]
Understand "ask [something]" as discussing with it about.
Understand "tell [something]" as discussing with it about.
Understand "ask [something] about [any discussable thing]" as discussing with it about.
Understand "ask [something] about [text]" as babbling to it that.
Understand "ask [something] for [any discussable thing]" as discussing with it about.
Understand "ask [something] for [text]" as babbling to it that.
Understand "tell [something] that [any discussable thing]" as discussing with it about.
Understand "tell [something] that [text]" as babbling to it that.
Understand "tell [something] about [any discussable thing]" as discussing with it about.
Understand "tell [something] that [text]" as babbling to it that.
Understand "talk to [something] about [any discussable thing]" as discussing with it about.
Understand "talk to [something] about [text]" as babbling to it that.
Understand "talk to" as babbling to it that.
Understand "talk to [something]" as discussing with it about.
Rule for supplying a missing second noun when discussing with about:
say "[italic type]You must be more specific about what you want to discuss.[roman type][line break]" instead;
Should the game suggest discussing with something about something conversable:
it is a good suggestion.
Should the game suggest targetless discussing something conversable:
it is a good suggestion.
Before discussing with about:
now the second noun is hinted;
continue the action.
Check discussing with it about:
if the noun is the player, say "[self-talking]" instead;
if the noun is not the guard and the noun is not the creature, say "[inanimate-talking]" instead;
if the second noun is not discussable, try babbling to the noun that instead;
if the noun is the creature and the creature response of the second noun is "":
try babbling to the noun that instead;
if the noun is the guard and the guard response of the second noun is "":
try babbling to the noun that instead.
Carry out discussing with the creature about:
if the creature response of the second noun is not "":
say "[creature response of the second noun][line break]";
now the creature is spoken;
otherwise:
try babbling to the creature that instead.
Carry out discussing with the guard about:
if the guard response of the second noun is not "":
say "[guard response of the second noun][line break]";
now the guard is spoken;
otherwise:
try babbling to the guard that instead.
Does the player mean discussing with about the noun: it is very likely. [helps with topics like "himself"]
Targetless discussing is an action applying to one visible thing.
Targetless babbling is an action applying to one topic.
Targetless discussing something is unktonking.
Understand "a [any discussable thing]" as targetless discussing.
Understand "a [text]" as targetless babbling.
Understand "t [any discussable thing]" as targetless discussing.
Understand "t [text]" as targetless babbling.
Understand "t" as targetless discussing.
Understand "talk about [any discussable thing]" as targetless discussing.
Understand "talk about [text]" as targetless babbling.
Understand "ask about [any discussable thing]" as targetless discussing.
Understand "ask about [text]" as targetless babbling.
Understand "tell about [any discussable thing]" as targetless discussing.
Understand "tell about [text]" as targetless babbling.
Understand "ask for [any discussable thing]" as targetless discussing.
Understand "ask for [text]" as targetless babbling.
Rule for supplying a missing noun when targetless discussing:
say "[italic type]You must be more specific about what you want to discuss.[roman type][line break]" instead;
Check targetless discussing:
if the guard is in the cell, try discussing with the guard about the noun instead;
if the creature is in the cell, try discussing with the creature about the noun instead;
try babbling to the player that "foo" instead.
Check targetless babbling:
if the guard is in the cell:
try babbling to the guard that "[the topic understood]" instead;
if the creature is in the cell:
try babbling to the creature that "[the topic understood]" instead;
try babbling to the player that "foo" instead.
Instead of asking someone (called the talker) to try discussing with the player about something (called the chat-topic):
try discussing with the talker about the chat-topic.
Instead of asking someone (called the talker) to try targetless discussing something (called the chat-topic):
try discussing with the talker about the chat-topic.