Escapade!
An interactive fiction by Juhana Leinonen (2008) - the Inform 7 source text
Contents
Previous
Next
Complete text
Book General
The creature is a neuter animal. It is not conversable. It is by the window. The description is "The creature is small, shorter than you, and pitch black. It has an oblong head, no ears, tiny black eyes, and sharp, black teeth clearly visible behind a lipless mouth.
A constant dripping of spit from between its teeth forms a small greenish puddle of saliva by its feet." The initial appearance is "[if the creature is unnamed]A black creature stands next to a burlap sack looking at you expectantly.[otherwise][one of][The creature] stands there next to a large burlap sack.[or][The creature] rummages through its sack for a while.[or][The creature] looks at you.[or][The creature] waves at you.[or]The creature wags its tail slowly from side to side.[or][The creature] leans against its sack.[at random]"
After looking:
say "[silent c][run paragraph on]"; [to suppress the random quips]
continue the action.
The creature can be present or absent. It is absent.
The creature can be spoken or silent. It is silent.
The creature can be first name basis or unnamed. It is unnamed.
The creature can be mentioned by the guard. It is not mentioned by the guard.
The creature response of the creature is "[one of]'How the [bowdler] did you get in here?'[paragraph break]'What do you mean? I [italic type]live[roman type] in this [key castle]castle[endkey castle],' the creature replies.[or]'I'm still not so sure what you actually are,' you ask. 'I'm a trader,' [the creature] replies matter-of-factly.[paragraph break]You give up. 'Yes, but... ah, never mind.'[stopping]".
The guard response of the creature is "[one of]You lean closer to the door and whisper: 'There is some... [italic type]thing[roman type] in the cell with me!'[paragraph break][g]You are IMAGINING things![g] the guard yells.[or]'No, I mean it! Look at it, there the monster is!'[paragraph break]The guard squints. 'NOPE. CAN'T see ANYTHING,' he shouts.[stopping]".
After discussing with the guard about the creature:
now the creature is mentioned by the guard.
Understand "monster/beast" as the creature.
Understand "hr" and "trader" as the creature when the creature is first name basis.
[the parser understands dots as separators for a new command; the following changes h.r. to hr before parsing so X H.R. and such will work]
After reading a command (this is the delete the creature's dots from input rule):
let T be indexed text;
let T be the player's command;
replace the regular expression "(h\.r\.|h\.r|hr\.)" in T with "hr";
change the text of the player's command to T.
Instead of taking the creature:
try touching the creature.
Instead of eating the creature when the creature is present:
say "'If I don't get out of here soon, I might have to resort to cannibalism,' you inform the creature.
[c]You must be confused about who is the dinner and who is the eater here,' [the creature] replies.".
Instead of looking under the creature when the creature is present:
say "[c]Hey! That's just rude,' [the creature] shouts.".
Instead of searching the creature:
try touching the creature.
Instead of kissing the creature:
try touching the creature.
Instead of kissing the creature when the creature is present:
say "'We should conserve body temperature by curling up close together,' you suggest.
[c]One: I'm cold-blooded. Two: that's the most disgusting idea I've ever heard[if the player is naked] coming from a chubby naked man[end if],' [the creature] replies.".
Instead of answering the creature that:
say "[c]Nope,' the creature says.".
Instead of touching or attacking the creature:
say "You're too afraid to."
Instead of discussing with the ominous shapes about something:
say "You don't have the courage."
Instead of attacking the creature when the creature is present:
say "'I think I could overpower you if need be,' you muse.[paragraph break][c]Maybe by crushing me with your weight,' [the creature] replies. 'I don't suggest you to try, though. I'm sure I couldn't eat you all at once, but you'd be missing your trachea before you had time to start rolling.'".
Instead of touching the creature when the creature is present:
say "[c]If you want to keep that finger, I suggest you keep touching just yourself,' [the creature] threatens.".
Instead of pushing, pulling or turning the creature:
try touching the creature.
Instead of squeezing the creature when the creature is present:
say "'A hug, please?'[line break][insult wimpiness]".
Instead of smelling the creature:
say "There's a strange, slightly pungent smell to the creature.".
Instead of listening to the creature:
say "[silent c]It hisses and gurgles from time to time.".
Instead of tasting the creature when the creature is present:
say "'Would you mind if I licked you a bit?'
[c]Yes. Yes I very much would,' [the creature] objects.".
Instead of climbing the creature when the creature is present:
say "'I have a plan. First, I climb on you...' you start.
[c]Whoa, stop right there. Judging by step one, that's a [italic type]very bad plan[roman type],' [the creature] says.".
Carry out bribing the creature with:
if the creature is present:
say "[c]I don't take bribes. I trade,' [the creature] says.";
otherwise:
say "It's probably not in a position to unlock the door even with bribes."
Rule for deciding whether all includes the creature:
it does not.
[the following are substitutions for quotation marks. Whenever the creature talks, the flag is set that it has spoken, so random quips won't be shown.]
To say c:
say "'";
now the creature is spoken.
To say silent c: [this is when H.R. sighs or does something else that doesn't need the quotation marks but should set the flag anyway]
now the creature is spoken.
After discussing with the creature about:
now the creature is spoken;
continue the action.
Test c with "screw bulb/t creature".