Escapade!
An interactive fiction by Juhana Leinonen (2008) - the Inform 7 source text
Contents
Previous
Next
Complete text
The toilet hole is in the cell. It is by the window. The description is "It's a smelly little hole[if the player carries the toilet hole]. Incredibly enough you are carrying it with you[otherwise if the toilet hole is handled]. Incredibly enough it seems to be a portable model[end if].".
['handled' is a handy property here, since if the toilet hole is handled, we have picked it up and thus know of its uncommon properties]
Before listing nondescript items:
if the toilet hole is marked for listing and the toilet hole is not handled:
change the toilet hole to not marked for listing.
After examining the toilet hole when the toilet hole is part of something (called the surface):
say "The toilet hole is currently attached to [the surface]."
After examining something when the toilet hole is part of the noun:
say "The toilet hole is attached to it."
The creature response of the toilet hole is "[if the toilet hole is handled and the player carries the toilet hole]You dangle the hole in the air pinched between your thumb and index finger. [end if][if the toilet hole is handled]'What the [bowdler] is going on here[interrobang]'[paragraph break][c][The creature] shrugs. 'That's relatively common here. The [key previous owners]previous owners[endkey previous owners] of the [key castle]castle[endkey castle] did some freakish experiments. Things tend to be somewhat... [italic type]loose[roman type] around here.'[otherwise]'Just a hole in the ground? Am I supposed to... you know... in there?'[paragraph break]'What did you expect, chinese porcelain with chinchilla fur seat?' It then looks as if it remembered something and scratches the floor with its big toe. 'Well, to tell the truth there [italic type]was[roman type] such a toilet here, but I traded it for a set of fancy hubcaps.'"
The hubcaps are a conversable thing. Understand "hubcap" as the hubcaps. They are plural-named. The creature response is "'What use would you have for hubcaps?' you ask.[paragraph break]'They were bling-bling to the max,' [the creature] replies and you can't tell whether it's being serious or not."
Instead of entering the toilet hole:
say "It's way too small.".
Instead of looking under the toilet hole:
say "That's too hard to accomplish.".
Instead of opening the toilet hole:
say "It's already as open as it gets.".
Before closing the toilet hole:
say "There's no cover on it." instead.
Instead of touching the toilet hole:
say "It feels like air.".
Instead of squeezing the toilet hole:
say "You can't see any way how that could be possible.".
Instead of smelling the toilet hole:
say "Yuck.".
Instead of tasting the toilet hole:
say "You have put your tongue in many unsavory places, but even you realize this would not be the smartest move to make.[if the creature is present][line break][c]Good call,' [the creature] comments."
Instead of rubbing the toilet hole:
say "There's no surface to rub.".
[again, we need to make sure the game doesn't automatically take the hole as a part of some other action when the player doesn't yet "know" that they can take it.]
Inserting the toilet hole into something is hole-taking.
Putting the toilet hole on something is hole-taking.
Tying the toilet hole to something is hole-taking.
Giving the toilet hole to something is hole-taking.
Before hole-taking when the toilet hole is not handled (this is the stop hole-taking rule):
say "You need to be holding the toilet hole to do that.";
stop the action.
The stop hole-taking rule is listed first in the before rules.
[this makes the toilet hole listed last in the TAKE ALL command. Thanks to Roger for the solution.]
Should the game suggest taking the toilet hole: it is a passable suggestion.
Report taking the toilet hole for the first time:
if multiple taking:
say "Taken. Wait, what?" instead;
otherwise:
say "You pick up the hole from its corners and hold it with some disbelief[if the creature is present]. [c]Eww. That's not very hygienic,[c] [the creature] says[end if]." instead.
Instead of giving the toilet hole to the creature when the creature is present:
say "[c]If I put [italic type]a hole[roman type] in my [key trading-bag]sack[endkey trading-bag], what do you think would happen?' [the creature] asks. [c]All of my merchandise would fall out. That's what.'"
Instead of putting the toilet hole on something (called the surface):
try tying the toilet hole to the surface.
Instead of inserting the toilet hole into something (called the surface):
try tying the toilet hole to the surface.
Instead of tying the toilet hole to something:
say "That wouldn't help you escape."
Instead of tying the toilet hole to the player:
say "You would just spill your guts."
Instead of tying the toilet hole to the trapdoor when the trapdoor is closed:
say "You slap the hole on the trapdoor and you can see another room through it.[if the creature is present][line break]The creature says [c]Whoa.'"
Instead of tying the toilet hole to the trading-bag when the creature is present:
say "[c]Hey!' [the creature] shouts. 'My stuff would fall out!'".
Instead of inserting something into the toilet hole:
say "Better not. It would just get dirty and smelly."
To say attached the hole to something:
say "[one of][line break]'[if the tongue is numb]Hah heemh... uhihy[otherwise]That seems... unlikely[end if],' you say[if the creature is present and the tongue is not numb][c]I've seen stranger things around [key castle]here[endkey castle],' [the creature] shrugs[end if].[or][stopping]".
Instead of tying the toilet hole to the celldoor:
if the guard is in the cell:
say "Better not do that while the guard is watching. He would probably confiscate the hole.";
otherwise:
say "You slap the hole against the door. It sticks there and through it you can see the corridor on the other side.[attached the hole to something]";
now the toilet hole is part of the celldoor;
if the doorkey is known:
now the doorkey is in the cell. [so that it's "returned" when we know it's there (by having reached through the hole before)]
Instead of tying the toilet hole to the walls:
say "You put the hole on one of the walls. There's nothing else than more stone visible through it. You peel the hole back out.[if the creature is present][line break][c]Looks like it's not a very deep hole,[c] [the creature] remarks."
Instead of tying the toilet hole to the floor:
try dropping the toilet hole.
Report dropping the toilet hole:
say "You place the toilet hole back on the floor." instead.
Instead of taking the toilet hole when the toilet hole is part of something (called the attachee):
say "You peel the hole off [the attachee].";
remove the doorkey from play; [the door key is added in scope when the hole is slapped on the door.]
now the player carries the toilet hole.
Instead of touching the toilet hole:
try reaching through the toilet hole.
Instead of looking through the toilet:
if the toilet hole is part of the celldoor:
say "You can see through the door and into the corridor.";
otherwise:
say "Fortunately it seems to be empty."
Instead of calling the guard when the toilet hole is part of the celldoor:
say "Better not call the guard now. He would see the hole and foil your attempts at escape."